plugins {
	id 'java-library'
}

description = 'dariahsp - core library'

dependencies {
	api "de.unibamberg.minf.core:core-metamodel:$coreVersion"
	api "org.pac4j:spring-security-pac4j:$springPac4jVersion"
	api "org.pac4j:spring-webmvc-pac4j:$webmvcPac4jVersion"
	api "org.pac4j:pac4j-saml:$pac4jVersion"
	api "org.pac4j:pac4j-http:$pac4jVersion"
	implementation "org.springframework:spring-webmvc"
	implementation "javax.servlet:javax.servlet-api"
	
	compileOnly "org.projectlombok:lombok"
	annotationProcessor "org.projectlombok:lombok"
	
    testImplementation librarySets.commonTest
}

jar {
	enabled = true
}

task customFatJar(type: Jar) {
	manifest {
		attributes 'Main-Class': ' eu.dariah.de.dariahsp.BCryptPasswordCreator'
	}
	archiveClassifier = 'fatjar'
    dependsOn configurations.runtimeClasspath
    from {
        configurations.runtimeClasspath.findAll { it.name.endsWith('jar') }.collect { zipTree(it) }
    }
    exclude 'META-INF/*.RSA'
    exclude 'META-INF/*.SF'
    exclude 'META-INF/*.DSA'
	with jar
}

artifacts {
    archives customFatJar
}


publishing {
    publications {
        maven(MavenPublication) {
            from(components.java)
            artifact(sourcesJar) {}
            artifact(javadocJar) {}
            artifact(customFatJar) {}
        }
    }
}