plugins {
	id 'io.spring.dependency-management' version "1.0.10.RELEASE"
	id 'org.springframework.boot' version "2.3.5.RELEASE" apply false
}

allprojects {
	group = 'eu.dariah.de'
	version = '2.1.7-RELEASE'

	apply plugin: 'eclipse'

	repositories {
		maven {
            url = 'https://minfba.de.dariah.eu/nexus/repository/minfba-central/'
        }
	}

	ext {
		coreVersion = "6.5.4-SNAPSHOT"
		springPac4jVersion = "5.1.0"
		webmvcPac4jVersion = "4.0.1"
		pac4jVersion = "4.1.0"
		/*lombokVersion = "1.18.14"
		servletApiVersion = "4.0.1"
		jspApiVersion = "2.3.3"*/
		
        librarySets = [
            commonTest: [
    			"org.junit.jupiter:junit-jupiter-engine",
				"org.junit.jupiter:junit-jupiter-api",
				"org.junit.jupiter:junit-jupiter-params",
				"org.slf4j:slf4j-api",
                "org.slf4j:jcl-over-slf4j",
                "org.slf4j:log4j-over-slf4j",
    			"ch.qos.logback:logback-core",
    			"ch.qos.logback:logback-classic",
            ]
        ]
    }
}

subprojects {
	apply plugin: 'java'
 	apply plugin: 'maven-publish'
	apply plugin: 'io.spring.dependency-management'

	dependencyManagement {
	        imports {
	                mavenBom(org.springframework.boot.gradle.plugin.SpringBootPlugin.BOM_COORDINATES)
	        }
	}

    publishing {
        publications {
            maven(MavenPublication) {
                pom {
                    name = 'DARIAHSP'
                    url = 'https://gitlab.rz.uni-bamberg.de/dariah/dariahsp'
                    licenses {
                        license {
                            name = 'The Apache License, Version 2.0'
                            url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                        }
                    }
                    developers {
                        developer {
                            id = 'tgradl'
                            name = 'Tobias Gradl'
                            email = 'tobias.gradl@uni-bamberg.de'
                        }
                    }
                    scm {
                        connection = 'scm:git:git://gitlab.rz.uni-bamberg.de/dariah/dariahsp.git'
                        developerConnection = 'scm:git:ssh://gitlab.rz.uni-bamberg.de/dariah/dariahsp.git'
                        url = 'https://gitlab.rz.uni-bamberg.de/dariah/dariahsp/'
                    }
                    issueManagement {
                        system = 'GitLab'
                        url = 'https://gitlab.rz.uni-bamberg.de/dariah/dariahsp/issues'
                    }
                }
            }
        }
        repositories {
            maven {
                def releasesRepoUrl = "https://minfba.de.dariah.eu/nexus/repository/minfba-releases/"
                def snapshotsRepoUrl = "https://minfba.de.dariah.eu/nexus/repository/minfba-snapshots/"
                
                if (version.endsWith('SNAPSHOT') || version.endsWith('RELEASE')) {
                    credentials {
                        username project.hasProperty('nexususer') ? project.getProperty('nexususer') : ''
                        password project.hasProperty('nexuspass') ? project.getProperty('nexuspass') : ''
                    }
                    url = version.endsWith('SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl
                } else {
                    // Have a local test repo under buildDir to be able to test publish but only actually do publish when the version ending matches
                    url = "$buildDir/repo/"
                }
            }
        }
    }

    java {
        sourceCompatibility = JavaVersion.VERSION_11
    }

    tasks.withType(JavaCompile) {
        options.encoding = 'UTF-8'
    }

    task sourcesJar(type: Jar, dependsOn: classes) {
        classifier = 'sources'
        from sourceSets.main.allSource
    }

    task javadocJar(type: Jar, dependsOn: javadoc) {
        classifier = 'javadoc'
        from javadoc.destinationDir
    }

    artifacts {
        archives sourcesJar
        archives javadocJar
    }
}